RPA.Assistant

Create a button and execute the function as a callback when pressed.

Arguments

Examples

*** Keywords ***
First View
    Add Heading  Here is the first view of the app
    Add Button  Change View  Second View

Second View
    Add Heading  Let's build an infinite loop
    Add Button  Change View  First View

Add a checkbox element

Arguments

Adds a checkbox that indicates a true or false value. The selection will be available in the name field of the result, and the label text will be shown next to the checkbox.

The boolean default value will define the initial checked state of the element.

Examples

Add heading     Enable features
Add checkbox    name=vault        label=Enable vault       default=True
Add checkbox    name=triggers     label=Enable triggers    default=False
Add checkbox    name=assistants   label=Enable assistants  default=True
${result}=      Run dialog
IF    $result.vault
    Enable vault
END

Add a date input element.

Arguments

Displays a date input widget. The selection the user makes will be available as a date object in the name field of the result. The default argument can be a pre-set date as object or string in "YYYY-MM-DD" format, otherwise the current date is used.

Examples

Add heading       Enter your birthdate
Add Date Input    birthdate    default=1993-04-26
${result} =       Run dialog
Log To Console    User birthdate year should be: ${result.birthdate.year}

Add a drop-down element

Arguments

Creates a drop-down menu with the given options. The selection the user makes will be available in the name field of the result.

The default argument can be one of the defined options, and the dialog automatically selects that option for the input.

A custom label text can also be added.

Examples

Add heading     Select user type
Add drop-down
...    name=user_type
...    options=Admin,Maintainer,Operator
...    default=Operator
...    label=User type
${result}=      Run dialog
Log    User type should be: ${result.user_type}

Add a file element, which links to a local file

Arguments

Adds a button which opens a local file with the corresponding default application. Can be used for instance to display generated files from the robot to the end-user.

Optionally a custom label can be given for the button text. By default uses the filename of the linked file.

Examples

${path}=   Generate order files
Add heading    Current orders
Add file    ${path}    label=Current
Run dialog

Add a file input element

Arguments

Adds a native file selection dialog for inputting one or more files. The list of selected files will be available in the name field of the result.

By default opens up in the user's home directory, but it can be set to a custom path with the source argument.

The argument file_type restricts the possible file extensions that the user can select. The format of the argument is as follows: pdf,png,svg. For instance, an argument to limit options to Excel files could be: xls,xlsx.

To allow selecting more than one file, the multiple argument can be enabled.

Examples

# This can be any one file
Add file input    name=anything

# This can be multiple files
Add file input    name=multiple  multiple=True

# This opens the select dialog to a custom folder
Add file input    name=src       source=C:\Temp\Output\

# This restricts files to certain types
Add file input    name=types     file_type=pdf

# Every file input result is a list of paths
${result}=    Run dialog
FOR    ${path}    IN    @{result.multiple}
    Log    Selected file: ${path}
END

Add multiple file elements according to the given file pattern

Arguments

See the keyword Add file for information about the inserted element itself.

The keyword uses Unix-style glob patterns for finding matching files, and the supported pattern expressions are as follow:

If a filename has any of these special characters, they can be escaped by wrapping them with square brackets.

Examples

# Add all excel files
Add files    *.xlsx

# Add all log files in any subdirectory
Add files    **/*.log

# Add all PDFs between order0 and order9
Add files    order[0-9].pdf

Add an icon from a large gallery of icons.

Arguments

Examples

Add Heading    Check icon
Add Flet Icon  icon_name=check_circle_rounded  color=FF00FF  size=48
Run Dialog

Add a centered heading text element

Arguments

Supported size values are Small, Medium, and Large. By default uses the value Medium.

Examples

Add heading     User information  size=Large
Add heading     Location          size=Small
Add text input  address           label=User address
Run dialog

Add a hidden input element

Arguments

Adds a special hidden result field that is not visible to the user and always contains the given static value.

Can be used to keep user input together with already known values such as user IDs, or to ensure that dialogs with differing elements all have the same fields in results.

Examples

Add hidden input   user_id   ${USER_ID}
Add text input     username
${result}=         Run dialog
Enter user information    ${result.user_id}    ${result.username}

Add an icon element from RPA.Assistant's short icon list.

Arguments

Adds an icon which can be used to indicate status or the type of dialog being presented.

The currently supported icon types are:

The size of the icon can also be changed, to a given height/width of pixels.

Examples

Add icon              Warning    size=64
Add heading           Do you want to delete this order?
Add submit buttons    buttons=No,Yes
${result}=    Run dialog

Add an image element, from a local file or remote URL

Arguments

Adds an inline image to the dialog, which can either point to a local file path on the executing machine or to a remote URL.

By default the image is resized to fit the width of the dialog window, but the width and/or height can be explicitly defined to a custom value. If only one of the dimensions is given, the other is automatically changed to maintain the correct aspect ratio.

Examples

Add image      company-logo.png
Add heading    To start, please press the Continue button   size=Small
Add submit buttons    Continue
Run dialog

Add an external URL link element

Arguments

Adds a clickable link element, which opens the user's default browser to the given url. Optionally a label can be given which is shown as the link text, instead of the raw URL.

Examples

Add heading    An error occurred
Add text       See link for documentation
Add link       https://robocorp.com/docs    label=Troubleshooting
Run dialog

Create a button that leads to the next UI page, calling the passed keyword or function, and passing current form results as first positional argument to it.

Arguments

Examples

*** Keywords ***
Retrieve User Data
    # Retrieves advanced data that needs to be displayed

Main Form
    Add Heading  Username input
    Add Text Input  name=username_1  placeholder=username
    Add Next Ui Button        Show customer details  Customer Details

Customer Details
    [Arguments]  ${form}
    ${user_data}=  Retrieve User Data  ${form}[username_1]
    Add Heading  Retrieved Data
    Add Text  ${user_data}[phone_number]
    Add Text  ${user_data}[address]

Add a password input element

Arguments

Adds a text field that hides the user's input. The entered content will be available in the name field of the result.

For customizing the look of the input, the label text can be given to add a descriptive label and the placholder text can be given to act as an example of the input value.

Examples

Add heading    Change password
Add text input        username    label=Current username
Add password input    password    label=New password
${result}=    Run dialog
Change user password    ${result.username}  ${result.password}

Add radio button elements

Arguments

Creates a set of radio buttons with the given options. The selection the user makes will be available in the name field of the result.

The default argument can be one of the defined options, and the dialog automatically selects that option for the input.

A custom label text can also be added.

Examples

Add heading     Select user type
Add radio buttons
...    name=user_type
...    options=Admin,Maintainer,Operator
...    default=Operator
...    label=User type
${result}=      Run dialog
Log    User type should be: ${result.user_type}

Add a slider input.

Arguments

*** Keywords ***
Create Percentage Slider
    Add Text    Percentage slider
    Add Slider  name=percentage  slider_min=0  slider_max=100
                thumb_text={value}%  steps=100  round=1

Add custom submit buttons

Arguments

The result field will always be called submit and will contain the pressed button text as a value.

If one of the custom options should be the preferred option, the default argument controls which one is highlighted with an accent color.

Examples

Add icon      Warning
Add heading   Delete user ${username}?
Add submit buttons    buttons=No,Yes    default=Yes
${result}=    Run dialog
IF   $result.submit == "Yes"
    Delete user    ${username}
END

Add a text paragraph element, for larger bodies of text

Arguments

Supported size values are Small, Medium, and Large. By default uses the value Medium.

Examples

Add heading   An error occurred
Add text      There was an error while requesting user information
Add text      ${error}   size=Small
Run dialog

Add a text input element

Arguments

Adds a text field that can be filled by the user. The entered content will be available in the name field of the result.

For customizing the look of the input, the label text can be given to add a descriptive label and the placholder text can be given to act as an example of the input value.

The default value will be assigned to the input field if the user doesn't complete it. If provided, the placeholder won't be shown. This is None by default. Also, if a default value is provided and the user deletes it, None will be the corresponding value in the results dictionary.

Examples

Add heading    Send feedback
Add text input    email    label=E-mail address
Add text input    message
...    label=Feedback
...    placeholder=Enter feedback here
${result}=    Run dialog
Send feedback message    ${result.email}  ${result.message}

Same as Run Dialog it will create a dialog from all the defined elements and block until the user has handled it. It will also add by default a submit and close buttons.

Arguments

Returns a result object with all input values.

For more information about possible options for opening the dialog, see the documentation for the keyword Run Dialog.

Examples

Add heading     Please enter your username
Add text input  name=username
${result}=      Ask User
Log    The username is: ${result.username}

Clear dialog and results while it is running.

Closes previously opened Column.

Raises LayoutError if called with no Column open, or if another layout element was opened more recently than a Column.

Close previously opened container.

Raises LayoutError if called with no Row open, or if another layout element was opened more recently than a row.

Close previously opened navbar.

Raises LayoutError if called with no Row open, or if another layout element was opened more recently than a row.

Close previously opened row.

Raises LayoutError if called with no Row open, or if another layout element was opened more recently than a row.

Close previously opened Stack.

Raises LayoutError if called with no Stack open, or if another layout element was opened more recently than a Stack.

Open a Column layout container. Following Add <element> calls will add items into that Column until Close Column is called.

*** Keywords ***
Double Column Layout
    Open Row
    Open Column
    Add Text      First item in the first column
    Add Text      Second item on the first column
    Close Column
    Open Column
    Add Text      First item on the second column
    Close Column
    Close Row

Open a single element container. The following Add <element> calls adds an element inside the container. Can be used for styling elements.

Arguments

*** Keywords ***
Padded Element With Background
    Open Container  padding=20  background_color=blue500
    Add Text        sample text
    Close Container

Create a Navigation Bar. Following Add <element> calls will add items into the Navbar until Close Navbar is called.

Arguments

Navbar doesn't clear when Clear Dialog is called.

Only one Navbar can be initialized at a time. Trying to make a second one will raise a LayoutError.

*** Keywords ***
    Go To Start Menu
        Add Heading  Start menu
        Add Text  Start menu content

    Assistant Navbar
        Open Navbar  title=Assistant
        Add Button   menu  Go To Start Menu
        Close Navbar

Open a row layout container. Following Add <element> calls will add items into that row until Close Row is called.

*** Keywords ***
Side By Side Elements
    Open Row
    Add Text  First item on the row
    Add Text  Second item on the row
    Close Row

Create a "Stack" layout element. Stack can be used to position elements absolutely and to have overlapping elements in your layout. Use Container's top and left arguments to position the elements in a stack.

Arguments

*** Keywords ***
    Absolutely Positioned Elements
        # Positioning containers with relative location values requires
        # absolute size for the Stack
        Open Stack  height=360  width=360

        Open Container  width=64  height=64  location=Center
        Add Text  center
        Close Container

        Open Container  width=64  height=64  location=TopRight
        Add Text  top right
        Close Container

        Open Container  width=64  height=64  location=BottomRight
        Add Text  bottom right
        Close Container

        Close Stack

Can be used to update UI elements when adding elements while dialog is running

Create a dialog from all the defined elements and block until the user has handled it.

Arguments

If the location argument is None it will let the operating system place the window.

Returns a result object with all input values.

When the dialog closes elements are cleared.

Examples

Add heading     Please enter your username
Add text input  name=username
${result}=      Run dialog
Log    The username is: ${result.username}

Set dialog title when it is running.

Arguments